Как сравнить два столбца в Excel

Справочник · Excel · 2 минуты чтения

Сначала решите, какая у вас задача:

построчно: совпадает ли значение в B2 со значением в C2, в B3 — с C3 и так далее (сверка цен в прайсе и в счёте);
два списка: есть ли каждое значение первого списка где-нибудь во втором, неважно в какой строке (кто из записавшихся не оплатил).

Как сравнить

Построчносравнить значения в одной строке

	A	B	C	D
1	Товар	Прайс	Счёт	Совпадает
2	Тетрадь	1,20	1,20	ИСТИНА
3	Ручка	0,85	0,90	ЛОЖЬ
4	Карандаш	0,40	0,40	ИСТИНА
5	Ластик	0,55	0,50	ЛОЖЬ

В D2 введите формулу и скопируйте её вниз:

Формула

=B2=C2

Понятнее с текстом и разницей:

Формула

=ЕСЛИ(B2=C2;"совпадает";"разница "&C2-B2)

Для Ручки получится «разница 0,05», для Ластика — «разница -0,05».

Текст = сравнивает без учёта регистра: «минск» = «Минск». С учётом регистра сравнивает СОВПАД: =СОВПАД(A2;B2).

Подсветить без формул. Выделите B2:C5 → «Главная» → «Найти и выделить» → «Выделить группу ячеек» → «отличия по строкам» → OK. Выделятся ячейки столбца C, не совпадающие с B, — закрасьте их заливкой.

Дальше: «Почему «одинаковое» не совпадает»

Два списканайти, чего нет во втором

	A	B	C
1	Записались	Оплатили	Оплата
2	Анна	Борис	есть
3	Борис	Дарья	есть
4	Вера	Анна	нет
5	Глеб		нет
6	Дарья		есть

В C2 введите формулу и скопируйте её вниз — она проверяет, встречается ли имя из A в списке B:

Формула

=ЕСЛИ(СЧЁТЕСЛИ($B$2:$B$100;A2)>0;"есть";"нет")

Не оплатили Вера и Глеб. Диапазон второго списка закреплён $, чтобы не сползал при копировании; с запасом до сотой строки — чтобы новые оплаты попадали в проверку. Отфильтруйте столбец C по «нет» — получится готовый список должников.

То же через функции поиска: =ЕСЛИ(ЕНД(ПОИСКПОЗ(A2;$B$2:$B$100;0));"нет";"есть") — ПОИСКПОЗ возвращает #Н/Д, если не нашла, а ЕНД превращает это в ИСТИНА.

Подсветить без формул. Выделите оба столбца → «Главная» → «Условное форматирование» → «Правила выделения ячеек» → «Повторяющиеся значения». Подсветятся значения, встречающиеся в выделении больше одного раза, — в том числе те, что есть в обоих списках.

Почему «одинаковое» не совпадает

Пробелы. «Анна » с пробелом в конце не равна «Анна». Проверка: =ДЛСТР(A2) покажет лишний символ. Уберите пробелы функцией =СЖПРОБЕЛЫ(A2) в соседнем столбце и сравнивайте уже его.
Число и текст. 1,20 числом и «1,20» текстом не равны. Текст обычно прижат влево; превратить в число можно формулой =ЗНАЧЕН(A2) или как описано в Формула не считается.
Невидимая разница в числах. Результаты расчётов с дробями могут отличаться в 15-м–16-м знаке (так компьютер хранит дроби), и сравнение даёт ЛОЖЬ, хотя на экране числа одинаковые. Для денег сравнивайте округлённые значения: =ОКРУГЛ(B2;2)=ОКРУГЛ(C2;2).
Буква ё и е, латинская и русская «с». Выглядят одинаково, но для Excel это разные символы.